title: Start
tags: start
---
<<detour InitParams>>
<<jump 开场>>
===

title: 开场
tags: linear
---
<<fade_out 0>>
<<hide_dialog>>

<<set_global_param Vol_general 0>>
//TODO: 【海浪声】
<<wait 2>>
jj: …只要愿意花工夫，<waitfor=0.1>坏掉的东西总是可以修好的。 #line:064318c
me: 就像生病一样吗？ #line:0787636
jj: 就像生病一样。 #line:0aaec52
me: …那姐姐呢？ #line:06e2595
jj: 姐姐… #line:0b33086
jj: 姐姐…<waitfor=0.2>恐怕要花很多很多工夫<br>才能修好呢。 #line:0fb7a29
me: 我想要试试。<waitfor=0.2>我不怕花工夫。 #line:0c13230
jj: …… #line:0038deb
jj: 那你要快点长大喔~小麦克斯韦妖。 #line:01c4501
//TODO: 【海浪声消退，时钟声淡入】

<<stop_music event:/Music/music_bar>>

<<set_global_param dream1Stage 0>>


<<set_global_param Vol_general 0.2>>
<<hide_dialog>>
<<wait 2>>

<<set_music_param event:/Amb/amb_beachsample beach_sample_stage 0.2>>
???: 喂。 #line:0c3c2ba 


<<hide_sprite>>
<<set_global_param dream1Stage 0.1>>
<<wait 3>>
<<set_global_param dream1Stage 0.2>>
->睁眼 #line:02e0a5f 
    <<set_music_param event:/Amb/amb_beachsample beach_sample_stage 0>>
    me: …… #line:0162fb8 
->…… #line:08fd9ad 
    ???: 喂！ #line:01ca3b4 
    <<set_music_param event:/Amb/amb_beachsample beach_sample_stage 0.1>>
    me: …… #line:040a6eb 
    ->…… #line:01c0e67 
        <<set_music_param event:/Amb/amb_beachsample beach_sample_stage 0>>
        一只冷冰冰的手在你额头上拍了一下。 #line:07ffbe9 
        me: 嗷…… #line:068a3c5 
    ->睁眼 #line:0be32a8 
        <<set_music_param event:/Amb/amb_beachsample beach_sample_stage 0>>
        me: …… #line:0b085ea
<<jump 教室苏醒>>
===

title: 教室苏醒
tags: linear
---
<<stop_music event:/Amb/amb_beachsample fade>>
<<set_global_param dream1Stage 0.6>>
<<show_sprite "D1S教室">>
<i>一个穿着卡其裤的男孩站在你的面前，<br>他的衣服上沾满了胡乱的墨迹。</i> #line:04c4490
me: …阿灿…？ #line:083f1d6
boy: 什么啊？<waitfor=0.2><br>你怎么会在课上睡着了？？ #line:093b81b
me: …我…<waitfor=0.1>做了一个很奇怪的梦。 #line:036489e
me: 我… #line:09b8068
->梦到机器人 #line:08e65c8 
    me: 我梦见我是一个机器人…<waitfor=0.1><br>大家都是机器人…… #line:0bfe290
    boy: 我呢？ #line:0a61e83
    me: 你……<waitfor=0.1>应该也是吧。 #line:0f1a9da
    boy: 哇！<waitfor=0.2>那应该很酷！ #line:0493422
    boy: 不过先别想你的那个梦了。<waitfor=0.2><br>我们还有要紧事要做呢。 #line:0459d59
->梦到我是医生 #line:0ea32e2 
    me: 我梦见…<waitfor=0.1>我成了一个医生…… #line:01245ec
    boy: 你成绩这么好，<waitfor=0.1>肯定会考上医生的。 #line:0be0e02
    boy: 你姐姐也会没事的。<waitfor=0.2><br>你肯定会把她治好的！ #line:08fe6de
    boy: 不过先别想你的那个梦了。<waitfor=0.2><br>我们还有要紧事要做呢。 #line:0f2ea1c
->不记得了 #line:0db9a05 
    me: 我…<waitfor=0.1>不记得梦的内容了。 #line:063d357
    boy: 你肯定就是太累了。<waitfor=0.2><br>你昨晚肯定又熬夜看书了吧。 #line:08caf8c
    boy: 别想你的那个梦了。<waitfor=0.2><br>我们还有要紧事要做呢。 #line:0e79910
<<set_global_param dream1Stage 0.7>>
boy: 你说过今天就要把它修好的。<waitfor=0.2><br>快来！ #line:0d5aa08
me: 谁？ #line:0daae78
boy: 你睡糊涂啦？<waitfor=0.2>快来吧！ #line:023c325
<i>男孩迫不及待地跑出了教室。</i> #line:0b62a5a
me: 喂！<waitfor=0.2>等下…… #line:0724d32
<<play_music event:/Music/mus_dream1>>
<<set_global_param dream1Stage 1>>
<<jump 教室>>
===

title: 教室
tags: hub
---
<<set_global_param Vol_general 1>>
<<detour 展示教室_Func>>
<<set_global_param dream1scene 0>>
<<detour 教室_入场>>

->离开教室 #line:02cd7da 
    <<hide_sprite>>
    <<jump 走廊>>
->观察 #line:0c9209f 
    <<detour 观察>>
    <<jump 教室>>
->趴回去再睡会 #line:0028a19 
    <<detour 趴回去再睡会>>
    <<jump 教室>>
===

title: 教室_入场
tags: detour
---
<i>你站在空荡荡的教室里。<waitfor=0.3 ><br>教室里空无一人，<waitfor=0.2>只有轻轻飘动的窗帘发出的扑梭声。</i> #line:0557c68
===

title: 观察
tags: detour
---
->窗外 #line:07f8e7b 
    <i>刺眼的阳光照在你的眼睛上，<waitfor=0.2><br>你一下子什么也看不清了。</i> #line:0bf7a33
    <i>忽然你感到<br>什么东西在你的脸上掠过，<waitfor=0.3><br>你退了回来。</i> #line:0138c7d
    <i>原来是窗帘啊。</i> #line:0d9556c
    <<once if $slept>>
        <i>窗台上的什么东西引起了你的注意。</i> #line:0e6015b
        【你获得了：羽毛】 #line:03ea994
    <<endonce>>
->黑板 #line:0514970
    <i>黑板上似乎还留着一些板书和记录。</i> #line:09a5060
    <i>你认为这些内容应该很简单，<waitfor=0.2><br>仔细一读却什么也看不懂。</i> #line:078fb75
    <i>你觉得有些心慌。</i> #line:0fce30a
->走廊 #line:07a50e3
    <i>走廊空荡荡的，<waitfor=0.2><br>时不时传来一些遥远的嬉闹声。</i> #line:03a2b9c
    <i>一阵风掠过，<waitfor=0.2><br>窗户在窗框上振动，<waitfor=0.3>发出轻轻的铛铛声。</i> #line:02d8b46
    <i>风停了。</i> #line:093de56
===

title: 趴回去再睡会
tags: detour
---
me: …… #line:00ab4f3 
<<hide_sprite>>
<i>你尝试清空思绪。</i> #line:043d77c
<i>有两只鸟好像落在了<br>窗户附近的树枝上，<br>欢快地鸣叫。</i> #line:003e9cb
<i>阳光照在你身上，暖暖的。</i> #line:0d1cbab
->醒来 #line:08cbcd5 
    me: …… #line:04dbccf 
    <<show_sprite "D1S教室">>
    <i>你睁开眼睛，听到翅膀扑朔的声音。</i> #line:0407462 
    <i>鸟儿飞走了。</i> #line:01c2891 
    <<detour 睡着_Set>>
===

title: 走廊
tags: hub
---
<<set_global_param dream1scene 1>>
<<once if $ppStage>=1 && $gameStage==0>>
    <<set $pphChecked=true>>
    <i>你走下楼梯，<br>火红的夕阳透过玻璃，<br>在整个走廊的空气里回荡。</i> #line:0dbf438
    <<show_sprite "D1S走廊2">>
    <<set $gameStage=1>>
<<endonce>>
<<detour 展示走廊_Func>>
<<detour 走廊_入场>>

->离开 #line:0719618  #deps:gameStage
    <<detour 离开_打量>>
    ->向后进入楼梯间 #line:0dd8dc1 
        <<jump 楼梯间>>
->女孩 #line:06c47ec #deps:ppStage,scj
    <<detour 女孩>>
    <<jump 走廊>>
->窗外<<if $gameStage == 0>> #line:03fa5f5 
    <<detour 走廊窗外>>
    <<jump 走廊>>
===

title: 离开_打量
tags: detour
---
<<once>>
    <i>你打量着这条走廊。<br>在你身后，走廊通向一个楼梯间；<br>在你身前，走廊曲折地延伸出去，<br>看不到尽头。</i> #line:0602eb0
<<endonce>>
===

title: 走廊_入场
tags: detour
---
<<if $ppStage!=2>>
    <i>你站在一条长长的走廊。<waitfor=0.2>阳光看起来很不错。<br><waitfor=0.2>一个穿着连帽卫衣的女孩正在玻璃上画画。</i> #line:0d69997
<<endif>>
===

title: 走廊窗外
tags: detour
---
<<show_sprite "D1S走廊-小镇">>
<i>很普通的小镇，<waitfor=0.1>远处是层层叠叠的小楼。<waitfor=0.2><br>你有一阵熟悉的感觉，<waitfor=0.2>好像其中一幢就是你的家。</i> #line:0304d72
<i>阳光照在你身上，暖暖的。</i> #line:0650718
===

title: 楼梯间
tags: hub
---
<<set_global_param dream1scene 2>>
<<hide_sprite>>
<<detour 展示楼梯间_Func>>
<<detour 楼梯间_入场>>

->向上 #line:04603ff 
    <<hide_sprite>>
    <<jump 天台>>
->返回 #line:0f6c1f1 
    <<jump 走廊>>
===

title: 楼梯间_入场
tags: detour
---
<i>你站在满是灰尘的楼梯间，<br>上面似乎就是天台。</i> #line:0c3fb6b
===

title: 女孩
tags: detour
---
<<detour 女孩_入场>>
???: …… #line:06cc492 
->交谈 #line:0f5967d #deps:ppStage,scj
    <<detour 女孩_交谈>>
->走开 #line:09e6d06 
===

title: 女孩_入场
tags: detour
---
<<detour 展示佩佩_Func>>
<<if $gameStage==0>>
    <i>女孩正在玻璃上调试着颜色。<waitfor=0.2><br>看到你靠近，<waitfor=0.2>她不好意思地停下了笔。</i> #line:0043186
<<elseif $gameStage==1>>
    <i>女孩正专注地向天空中添加红色，<br>没有注意到你的靠近。</i> #line:0a76fb1
<<else>>
    <i>女孩正专注地向天空中添加颜色，<br>没有注意到你的靠近。</i> #line:0d39c58
<<endif>>
===

title: 女孩_交谈
tags: detour
---
<<if $ppStage==0>>
    <<detour 女孩_初次交谈>>
<<elseif $ppStage==1>>
    <<detour 女孩_等待矢车菊>>
<<elseif $ppStage==2>>
    <<detour 女孩_已完成>>
<<endif>>
===

title: 女孩_初次交谈
tags: detour
---
<<once>>
    me: 这是…<waitfor=0.1>在画什么？ #line:079eea7
    girl: 对不起…<waitfor=0.1>我这就擦掉。 #line:0deb6fb
    me: 不不…<waitfor=0.1>我只是好奇。 #line:0203769
    girl: 啊…<waitfor=0.1>我只是…<waitfor=0.1>在想天空的颜色。 #line:0125ea8
    me: 天空的颜色？<waitfor=0.2>蓝色么不是。 #line:0ad6d74
    girl: 没错，<waitfor=0.1>但是……<waitfor=0.1>蓝色也有很多种蓝呢。 #line:0a81ec2
    girl: 天蓝色，<waitfor=0.1>湖蓝色，<waitfor=0.1>宝蓝色，<waitfor=0.1><br>海军蓝，<waitfor=0.1>矢车菊蓝…… #line:046d021
    girl: 你说的对…<waitfor=0.1>应该是矢车菊的蓝才对呢。 #line:021390b
    me: 我？ #line:0ab7567
    girl: 不管怎样…<waitfor=0.1>先把另一种颜色调出来吧。 #line:0d4cf1d
    <i>女孩开始自顾自地调试起颜色。</i> #line:02e75b6
<<else>>
    girl: 嗯…<waitfor=0.1>应该再加一点白才对… #line:051929d
    <i>女孩一边调试颜色一边自言自语。</i> #line:05b0c2f
<<endonce>>
===

title: 女孩_等待矢车菊
tags: detour
---
me: 这是…<waitfor=0.1>你画的？ #line:03c63c9
girl: …是…<waitfor=0.1>但颜色还是不太对。 #line:031d1ac
girl: 矢车菊蓝…<waitfor=0.1>总还是差一点啊。 #line:07f05d1
<<if $scj==1>>
    ->矢车菊 #line:0f763eb 
        <<detour 递矢车菊>>
<<else>>
    me: 除了颜色…<waitfor=0.1>你能画些别的东西吗？ #line:061aeb0
    <i>女孩似乎没有听见你说话。</i> #line:0cce274
<<endif>>
===

title: 递矢车菊
tags: detour
---
<<show_sprite "递出矢车菊夕阳">>
girl: 这是…<waitfor=0.1>给我的？ #line:0fd6134
me: 希望这值得。 #line:00f67c4 
girl: （笑）会的。 #line:063cdb2 
<<detour 递矢车菊_Set>>
girl: ……嗯…<waitfor=0.1>闭上眼睛吧。 #line:0dfb357
<<hide_sprite>>
girl: 好了。 #line:03a21b0 
<<show_sprite "D1S佩佩3">>
<i>女孩看着自己的作品出神。</i> #line:09b6db4 
me: 除了颜色…<waitfor=0.1>你能画些别的东西吗？ #line:038e79e
girl: 别的东西？ #line:0fd97ed 
me: 比如说…<waitfor=0.1>一扇本该存在的门。 #line:018c2f5
girl: 啊，<waitfor=0.1>我知道你是什么意思。（笑） #line:04369ab 
girl: 不过，<waitfor=0.1>门后面你要找的东西，<waitfor=0.1><br>我可画不出来喔。 #line:071eeb3
<i>你发现从这里正好可以<br>透过玻璃看到天文台。</i> #line:026ad07
<i>女孩沾了沾颜料，<br>一边哼歌一边继续涂画着。</i> #line:006fb3e
===

title: 女孩_已完成
tags: detour
---
girl: <i>女孩一边哼歌一边继续涂画着，<br>没有听到你的声音。</i> #line:01ef1ed
===

title: 天台
tags: hub
---
<<set_global_param dream1scene 3>>
<<detour 天台_入场>>

->检查 #line:0b329d5 #deps:gameStage
    <<detour 天台检查>>
    <<jump 天台>>
->上去<<if $gameStage<2>> #line:0e52171 
    <<detour 上去_与阿灿_开场>>
    ->远眺 #line:0f60517 
        <<detour 上去_远眺>>
        <<jump 天台>>
    ->下去 #line:069555a 
        <<hide_sprite>>
        <<jump 天台>>
->上去<<if $gameStage==2>> #line:0a361e8 
    <<detour 上去_画门_描述>>
    ->进入天文台 #line:04adc32 
        //你进门又走上一圈旋转楼梯，进入了一个昏暗圆形的房间。 #line:0c07ecc 
        <<hide_sprite>>
        <<jump 天文台>>
->下楼<<if $gameStage<2>> #line:0bf285a #deps:gameStage
    <<hide_sprite>>
    <<jump 走廊>>
<<jump 天台>>
===

title: 天台_入场
tags: detour
---
<<if $gameStage == 0>>
    <<detour 展示天台_Func>>
    <i>你站在教学楼的楼顶，<waitfor=0.1>视野开阔。<waitfor=0.2>阳光照在头顶有些发烫，<waitfor=0.1>风也暖暖的。<br>天文台的环形走廊高高的，<waitfor=0.2>阿灿正靠在上面发呆。</i> #line:0d3ce27
    <<once>>
        boy: 喂！<waitfor=0.2>上来！ #line:061bd66
        me: 你刚才说…<waitfor=0.1>我们要修谁？ #line:0fbf127
        boy: 你睡糊涂了吧，<waitfor=0.1>你要修理谁？<waitfor=0.2><br>亏你还想做医生呢！ #line:0292c23
        me: 我… #line:032bd1e 
        me: 我睡糊涂了。 #line:02ac5f7 
        <<hide_dialog>>
        <<wait 0.5>>
        <i>阿灿指向了天文台。</i> #line:03ef5a4 
        boy: 你自己说的啊，<waitfor=0.1>要把这个修好。 #line:0321859
        me: 天文台？为什么？ #line:059af3c
        boy: 拜托，<waitfor=0.1>你自己说的，<waitfor=0.1>你说要替她修好的。 #line:0b879a6
        <<hide_dialog>>
        <<wait 0.5>>
        me: 她…<waitfor=0.1>么…… #line:054776d
        //boy: 什么啊？<waitfor=0.2><br>什么梦啊，你在说什么啊？ #line:04ceb1f
        boy: 不过…<waitfor=0.1>它的入口在哪里呢…<waitfor=0.1><br>门怎么不存在了？<waitfor=0.2>奇怪。 #line:09585b5
        boy: 这下可怎么进去啊…… #line:0f47162
        <<detour 天台首次剧情_Set>>
    <<endonce>>
<<elseif $gameStage == 1>>
    <<once>>
        <<show_sprite "D1S天台-山2">>
        <<if $pphChecked==false>>
            <i>一眨眼的功夫，<waitfor=0.2>你发现天已经变成了火红色，<br>像油墨画一样。</i> #line:0376342
        <<else>>
            <i>火红色的天，像油墨画一样。</i> #line:0c2c51b 
        <<endif>>
    <<endonce>>
    <<detour 展示天台_Func>>
    <i>你站在教学楼的楼顶，视野开阔。<br>空气中似乎有种熟悉的<br>令人昏昏沉沉的气味……</i> #line:0325825
<<else>>
    <<detour 展示天台_Func>>
    <i>你站在教学楼的楼顶，视野开阔。<br>天蓝蓝的，风也有点儿冷了。<br>你感觉好像有人在喊你。</i> #line:0f4be5a 
<<endif>>
===

title: 天台检查
tags: detour
---
->窗户 #line:03e43b8 
    <i>天文台下面有一排窗户。<br>里面看起来是一个布满灰尘的走廊，<br>走廊的两端没有门，<waitfor=0.2>也没有窗。</i> #line:06ee6b8
    <i>很奇怪。<br>似乎从来没有人进去过，<waitfor=0.2>也从来没有人能进去。</i> #line:0f4c9c2
->地上<<if $gameStage < 2>> #line:06fcea6 #deps:gameStage
    <<if $gameStage==0>>
        <<if $scj == 0>>
            <<show_sprite "D1S天台-地板矢车菊1">>
        <<else>>
            <<show_sprite "D1S天台-地板1">>
        <<endif>>
    <<else>>
        <<if $scj == 0>>
            <<show_sprite "D1S天台-地板矢车菊2">>
        <<else>>
            <<show_sprite "D1S天台-地板2">>
        <<endif>>
    <<endif>>
    <i>地上排布着黑乎乎脏兮兮的隔热砖。<waitfor=0.2>太阳把地板晒得很烫。</i> #line:08d113b
    <i>门在哪里呢？</i> #line:0bb74cd
    boy: 你在找什么啊？<waitfor=0.2><br>入口怎么可能在地上啦。 #line:0de80f3
    <<if $scj==0>>
        <i>你注意到了不起眼角落里的什么东西。</i> #line:0a5cf5d 
        <<detour 捡起矢车菊_Set>>
        【获得：矢车菊】 #line:0229f7b 
    <<endif>>
    <i>你直起腰。<br>背上的衣服沾满了汗，<waitfor=0.2>垂坠下来，<waitfor=0.2>带进凉飕飕的空气。</i> #line:0f99bb3
->远眺 #line:06a03c9 
    <<detour 展示山_Func>>
    <i>小镇的尽头是一座绿绿的小山丘，<waitfor=0.4><br>小山丘的那边是另一座小山丘，<waitfor=0.4><br>小山丘的那边是另一座小山丘……</i> #line:0a12383
===

title: 上去_与阿灿_开场
tags: detour
---
<i>环形走廊很高，你走到阿灿身边。</i> #line:0545696 
boy: 你找到门在哪里了吗？ #line:00d0860 
me: 还没呢。 #line:0eecfc0 
boy: 啊？<waitfor=0.2>这下怎么办啊。<waitfor=0.2><br>我还怎么变成星星啊…… #line:021452a 
===

title: 上去_远眺
tags: detour
---
<<if $gameStage==0>>
    <<show_sprite "D1S天台-山1">>
<<elseif $gameStage==1>>
    <<show_sprite "D1S天台-山2">>
<<endif>>
boy: 你看到那边那座山了吗？ #line:0a53d71
me: 嗯哼。 #line:05e0384
boy: 你知道吗？<waitfor=0.2>山的南边就是大海。 #line:01d486a
me: 海不是在东边吗？ #line:03b0c59
boy: 这只是一种比喻啦！ #line:06984b6
boy: 山的南边的南边…<waitfor=0.1><br>只要你走得足够远，<waitfor=0.1><br>总会走到海边的。 #line:0314896
<i>你眯起眼睛使劲向远处望，<br>但远处好像被什么雾笼盖住了。</i> #line:0fb72c4
boy: 不过，<waitfor=0.1>现在还是先找天文台的入口吧。 #line:0fb2c0b
===

title: 上去_画门_描述
tags: detour
---
<i>墙上洋洋洒洒地画着一扇金属门，<br>门敞开着，<br>里面似乎有人在呼唤你。</i> #line:0124137
===

title: 天文台
tags: hub
---
<<set_global_param dream1scene 4>>
<<detour 展示天文台_Func>>
<<detour 天文台_入场>>

->观察 #line:081897d #deps:wyjStage
    <<detour 天文台观察>>
    <<jump 天文台>>
->望远镜 #line:00798be #deps:wyjStage
    <<detour 望远镜_开场>>
    ->安装目镜<<if $wyjStage == 2>> #line:04d4386 
        <<detour 安装目镜>>
        ->往里看 #line:0724b3e 
            <<jump 海边>>
        ->返回 #line:0c2845b 
            <<jump 天文台>>
    ->往里看<<if $wyjStage == 3>> #line:02f0aa3 
        <<hide_sprite>>
        <<jump 海边>>
    ->往里看<<if $wyjStage != 3>> #line:02f0aa4
        <<detour 往里看>>
        <<jump 天文台>>
->出去 #line:09312e4 
    <<hide_sprite>>
    <<jump 天台>>
===

title: 天文台_入场
tags: detour
---
<i>你站在一间昏暗的圆形房间里。<waitfor=0.2><br>房间的正中央是一台天文望远镜，<waitfor=0.2>看起来很久没人用了。<waitfor=0.2><br>房间一片死寂，<waitfor=0.2>地上、桌上，<waitfor=0.2>遍布着灰尘。</i> #line:0a229cf
<<if $wyjStage == 1>>
    <<set_global_param dream1Stage 2>>
    <i>手上的目镜沉甸甸的。<br>看起来只是胶圈坏了。</i> #line:083c3be
<<elseif $wyjStage == 2>>
    <<set_global_param dream1Stage 2.5>>
    <i>空气仿佛正在变得模糊而潮湿。</i> #line:0a115bc 
<<endif>>
<<once>>
    me: 阿灿？ #line:0befebd 
    me: 人呢…… #line:0f822b4 
<<endonce>>
===

title: 天文台观察
tags: detour
---
->日历 #line:01894bd 
    <i>黄黄的日历的顶端印着几个数字，<br>2后面跟着好多个0。</i> #line:0659b59
    <i>你伸手一碰，<br>那一页日历就像薄脆一样碎了。</i> #line:04f153a
    <i>下面的一页上面也印着几个数字，<br>看起来和上一页一样。</i> #line:0ce73c7
->便笺 #line:0fb3a58
    <<if $wyjStage == 0>>
        <i>望远镜上贴着一张黄色的便笺。</i> #line:0179879 
        hs: 你跑到哪里去了？<waitfor=0.2><br>我先上去，<waitfor=0.1>不等你啦 :P #line:0cbc819
    <<elseif $wyjStage == 1>>
        <i>望远镜上贴着一张褪色的便笺。</i> #line:0ff2298 
        hs: ……<waitfor=0.2>哪…<waitfor=0.1>去了…<waitfor=0.1>我先……<waitfor=0.1>不等…… #line:01ad7c7
        <i>字迹模糊不清，<br>看起来是很久很久以前写的。</i> #line:0529b64
    <<else>>
        <i>望远镜上贴着一张白色的便笺。</i> #line:092260e 
        <i>你碰了一下，<waitfor=0.2>便笺碎掉了。</i> #line:012a3a1 
    <<endif>>
->仪器 #line:007cbe4 #deps:wyjStage,hasCompressionRing
    <i>这些仪器看着很像你工作用的工具……</i> #line:0076043 
    <<if $wyjStage == 0>>
        <i>……不对，<br>你真的有那个工作吗？<br>你只是一个学生吧。</i> #line:0256c87 
    <<elseif $wyjStage == 1>>
        me: 只要…<waitfor=0.1>什么都能修好，<waitfor=0.1>对吧。<waitfor=0.2>你说的… #line:005b630 
    <<endif>>
    <<if $hasCompressionRing == false && $wyjStage < 2>>
        ->翻找零件 #line:09c5690 
            <i>大部分零件你都不认识。<br>不过你的运气不错。</i> #line:04bff73 
            ->完好的压缩环 #line:06c0942 
                <<if $wyjStage == 0>>
                    <i>你拿起一个小小的金属环。<br>你还不知道它能用在哪里。</i> #line:0c9a2d1
                <<else>>
                    me: 这下应该可以了。 #line:01ed9bc
                <<endif>>
                <<detour 找到压缩环_Set>>
    <<endif>>
===

title: 望远镜_开场
tags: detour
---
<<if $wyjStage == 0>>
    <i>望远镜很大，<br>上面刻着你看不懂的参数和型号。</i> #line:04e4782 
<<elseif $wyjStage == 1>>
    <i>望远镜很大，<br>不过比你想象的又要小一些。</i> #line:04d3d85 
<<else>>
    <i>望远镜上覆盖着厚厚的灰尘，<br>螺丝钉锈迹斑斑。</i> #line:0154dea 
    <i>原来它有这么旧吗？</i> #line:0bbc574 
<<endif>>
===

title: 安装目镜
tags: detour
---
<i>你记得这很困难。<br>但这比你印象中的轻松太多了。</i> #line:0edf096
me: 我修好了！<waitfor=0.2>对吧？<waitfor=0.2>我修好了…… #line:0e80e94
===

title: 往里看
tags: detour
---
<<if $wyjStage == 0>>
    <i>灰尘的声音在望远镜的空腔中回荡。<br>你眯起眼睛，努力想要看清楚。</i> #line:08aff34 
    <<set_global_param dream1Stage 2.4>>
    <<hide_sprite>>
    <i>咔哒一声，什么东西掉了下来。</i> #line:00f87b1 
    me: 哎呀… #line:07be273 
    ->接住 #line:0f8dd82 
        <i>你的手上拿着望远镜的目镜，<br>看起来就像小号的望远镜。</i> #line:0b032ff 
        <i>除此之外，<br>还有一个断成两半的环。<br>看起来是用来固定目镜的零件。</i> #line:0daf5f6 
        <<detour 目镜掉落_Set>>
<<elseif $wyjStage == 1 || $wyjStage == 2>>
    <<set_global_param dream1Stage 3>>
    <i>目镜原来在的位置上<br>是一个黑漆漆的洞。</i> #line:02bcbcb
    <i>往里面看去什么也没有，<br>只能听到灰尘的声音。</i> #line:0c4d195
    //TODO: 增加海浪音量
<<endif>>
===

title: 海边
tags: linear
---
<<stop_music event:/Music/mus_dream1 fade>>
<<hide_sprite>>
<i>你的身体仿佛正在黑暗中褪去。</i> #line:0da0c8f 
<<set_global_param dream1scene 5>>
<<showcase_fade_out>>
<<play_sfx "event:/Scriptal/sea_loop">>
<<set_global_param prologueDreamStage 1>>
<<play_timeline 星空到海浪>>
<<set_global_param dream1Stage 5>>
<<wait 2>>
jj: 你不该来这的。 #line:0df4d91 
me: 我也不想梦见你。<waitfor=0.2>可是…… #line:0ec80fc 
me: 不管梦的内容是什么……<waitfor=0.1><br>最后总会到这儿来，<waitfor=0.1>对吧。 #line:0b49833 
jj: 对或者不对，<waitfor=0.1>取决于你自己。 #line:0d90409 
me: 假如…… #line:0cf7ae6 
me: 假如你是真的就好了。 #line:02bbbbc 
//TODO: (海浪声)
<i>你仿佛感觉自己的手被握住了。</i> #line:025dad2 
jj: 假如我是真的，<waitfor=0.1><br>我会希望我是假的。 #line:018c643 
jj: 我还希望当你醒来，<waitfor=0.1><br>你就会忘记我。 #line:05b81f4 

me: 你知道么？ #line:07f5b5e 
me: 现实里不是所有东西坏了都能修好的。 #line:0ab64a2 
me: 这就是它们把你写进我的原型的原因。 #line:055f6cf 
me: 一个永远不可能被修好的……<waitfor=0.1><br>一个无法被完成的遗憾。 #line:07fee71 
me: 一个固执的…<waitfor=0.1>偏执的……<waitfor=0.1>有缺陷的…… #line:070fc03 

jj: 不。你已经做得很好了。 #line:0989b0e 
jj: 你是一个很棒的医生，<waitfor=0.1>不是吗？ #line:052f57a 
jj: 毕竟，<waitfor=0.1>我知道你是来做什么的。 #line:05c73fe 

me: 姐姐…… #line:099fc97 

jj: 姐姐愿意被*解决*。 #line:00fc25d 

<i>你没有说话。<br>站起身，海风吹在你的脸上，<waitfor=0.2>咸咸的，<waitfor=0.4>让人反胃。</i> #line:0185dd3 
me: 姐姐！ #line:017c7f1 
<i>海风吹在你的脸上，<br>迅速地吞没了你的回声。</i> #line:012ae52 
<i>扑通！</i> #line:0adf6d2 
<i>你把手里的东西远远地抛进了大海里。</i> #line:029a7e3 
me: 我再也不欠你什么了！ #line:0597cda 

jj: 你本来就不欠我什么。 #line:0fa59bb 
<i>姐姐的声音变得不稳定起来。</i> #line:060d93b 

me: …我本来就…<waitfor=0.1>不欠你什么。 #line:0ebcd24 

<i>姐姐笑了。<waitfor=0.5><br>声音越来越遥远，<waitfor=0.2><br>像是从门的另一边传来的。</i> #line:0ca4d3b 
jj: 该醒来了，<waitfor=0.4>路斯。 #line:03c9e3c 


<<hide_dialog>>
<<wait 2>>
<<stop_sfx "event:/Scriptal/clock" fade>>
<<stop_sfx "event:/Scriptal/sea_loop" fade>>
<<set_global_param Vol_general 1>>
<<showcase_fade_in_sync 0.1>>
<<wait  2>>
//<i>闹钟声逐渐响起，又被按掉。</i> #line:0c79c2f 
<<play_timeline 醒来>>
// <<wait 1>>
// <i>你睁开眼睛，眼神平和而冷淡。</i> #line:0829e5d 
<<NextYarn>>
===