title: Start
tags:
position: 250,-2611
---

<<declare $started=false>>

<<declare $slept=false>>

<<declare $pphChecked=false>>

<<declare $scj=0>>
<<declare $ym=0>>
<<declare $zs=0>>

<<declare $swam=0>>


<<declare $gameStage=0>>
//————————————————初始化参数————————————————
<<hide_obj>>
???: 喂。

->睁眼
    me: ……
    <<jump hs_教室>>
->……
    ???: 喂！
    me: ……
    ->……
        你感到一只冷冰冰的手在你额头上拍了一下。
        me: 嗷……
    ->睁眼
         me: ……
        <<jump hs_教室>>
<<jump hs_教室>>
===




title: hs_教室
tags:
position: 250,-2611
---
<<show_obj "教室.png">>
一个穿着卡其裤的男孩站在你的面前，他的衣服上沾满了胡乱的墨迹。
me: …阿灿…？
阿灿: 什么啊？你怎么会在课上睡着了？？
me: …我…做了一个很奇怪的梦。
me: 我…
->梦到机器人
    me: 我梦见我是一个机器人…大家都是机器人……
    阿灿: 我呢？
    me: 你……应该也是吧。
    阿灿: 哇！那应该很酷！
    阿灿: 不过先别想你的那个梦了。我们还有要紧事要做呢。
->梦到我是医生
    me: 我梦见…我成了一个医生……。
    阿灿: 你成绩这么好，肯定会考上医生的。
    阿灿: 你姐姐也会没事的。你肯定会把她治好的！
    阿灿: 不过先别想你的那个梦了。我们还有要紧事要做呢。
->不记得了
    me: 我…不记得梦的内容了。
    阿灿: 你肯定就是太累了。你昨晚肯定又熬夜看书了吧。
    阿灿: 别想你的那个梦了。我们还有要紧事要做呢。
阿灿: 你说过今天就要把它修好的。快来！
me: 谁？
阿灿: 你睡糊涂啦？快来吧！
男孩迫不及待地跑出了教室。
me: 喂！等下……
<<jump 教室>>
===




title: 教室
tags:
position: 250,-2611
---
<<show_obj "教室.png">>
//————————————————展示教室图片————————————————

【你站在空荡荡的教室里，教室里空无一人，只有轻轻飘动的窗帘发出的扑梭声】
->离开教室
    <<jump 走廊>>
->观察
    ->窗外
        刺眼的阳光照在你的眼睛上，你一下子什么也看不清了。
        忽然你感到什么东西在你的脸上掠过，你退了回来。
        原来是窗帘啊。
        <<if $slept==true && $ym==0>>
            <<set $ym=1>>
            窗台上的什么东西引起了你的注意。
            【你获得了：羽毛】
        <<endif>>
    ->黑板
        黑板上似乎还留着一些板书和记录。
        你认为这些内容应该很简单，仔细一读却什么也看不懂。
        你觉得有些心慌。
        <<if $zs==0>>
            <<set $zs=1>>
            【你获得了：被遗忘的知识】
        <<endif>>
    ->走廊
        走廊空荡荡的，时不时传来一些遥远的嬉闹声。
        一阵风掠过，窗户在窗框上振动，发出轻轻的铛铛声。
        风停了。
->趴回去再睡会
    me: ……
    <<hide_obj>>
    你尝试清空思绪。
    有两只鸟好像落在了窗户附近的树枝上，欢快地鸣叫。
    阳光照在你身上，暖暖的。
    ->醒来
    me: ……
    <<show_obj "教室.png">>
    你睁开眼睛，听到翅膀扑朔的声音。
    鸟儿飞走了。
    <<set $slept = true>>
<<jump 教室>>
===





title: 走廊
tags:
position: 250,-2611
---
<<if $gameStage==1 && $pphChecked==false>>
    <<set $pphChecked=true>>
    【你走下楼梯，一抹红色扑地撞在了你的脸上。】
    <<show_obj "走廊2.png">>
<<endif>>
<<if $gameStage==0>>
    <<show_obj "走廊.png">>
<<else>>
    <<show_obj "走廊2.png">>
<<endif>>
<<if $ppStage!=3>>
    【你站在一条长长的走廊。阳光看起来很不错。一个穿着连帽卫衣的女孩正在玻璃上画画。】
<<else>>
    【你站在一条长长的走廊。夕阳看起来很不错，空气冷冷的，闻起来像是露水的味道。】
<<endif>>
->离开
    <<if $zlChecked==false>>
        你打量着这条走廊。在你身后，走廊通向一个楼梯间；在你身前，走廊曲折地延伸出去，看不到尽头。
        <<set $zlChecked=true>>
    <<endif>>
    ->向后进入楼梯间
        <<hide_obj>>
        <<show_obj "楼梯间.png">>
        【你站在满是灰尘的楼梯间。楼梯间上面似乎是顶楼，下面则传来阵阵水声和唱歌的声音。】
        ->向上
            <<jump 天台>>
        ->向下
            <<jump 泳池>>
        ->返回
    ->向前探索
        你沿着走廊向前走。
        <<hide_obj>>
        走廊很长…仿佛没有尽头……
        <<jump 走廊深处>>
->女孩<<if $ppStage!=3>>
    <<if $gameStage==0>>
        【女孩正在用水彩笔在窗户上涂抹颜色，绿色的玻璃被涂成了大片的蓝色。看到你靠近，她不好意思地停下了笔。】
    <<else>>
        【女孩正专注地向天空中添加红色，没有注意到你的靠近。】
    <<endif>>
    ???: ……
    ->交谈
        <<if $ppStage==0>>
            <<set $ppStage=1>>
            me: 这是…在画什么？
            女孩: 对不起…我这就擦掉。
            me: 不不…我只是好奇。
            女孩: 啊…我只是…在想天空的颜色。
            me: 天空的颜色？蓝色么不是。
            女孩: 没错，但是……蓝色也有很多种蓝呢。
            女孩: 天蓝色，湖蓝色，宝蓝色，海军蓝，矢车菊蓝……
            女孩: 你说的对…应该是矢车菊的蓝才对呢。
            me: 我？
            女孩开始自顾自地调试起颜色。
        <<elseif $ppStage==1>>
            女孩: 嗯…应该再加一点白才对…
            女孩一边调试颜色一边自言自语。
        <<elseif $ppStage==2>>
            me: 这是…你画的？
            女孩: …是…但颜色还是不太对。
            女孩: 矢车菊蓝…总还是差一点啊。
            <<if $scj==0>>
                me: 除了颜色…你能画些别的东西吗？
                女孩似乎没有听见你说话。
            <<endif>>
            ->矢车菊<<if $scj==1>>
                女孩: 这是…给我的？
                me: 希望这值得。
                女孩: （笑）会的。
                <<set $gameStage =2>>
                <<set $ppStage=3>>
                女孩: ……嗯…闭上眼睛吧。
                <<hide_obj>>
                女孩: 好了。
                <<show_obj "走廊3.png">>
                女孩看着自己的作品出神。
                me: 除了颜色…你能画些别的东西吗？
                女孩: 别的东西？
                me: 比如说…一扇本该存在的门。
                女孩: 啊，我知道你是什么意思。（笑）
                女孩哼着歌走掉了。
        <<endif>>
    ->走开
->窗外
    看起来是一个很普通小镇，远处是层层叠叠小楼。你有一阵熟悉的感觉，好像其中一幢就是你的家。
    阳光照在你身上，暖暖的。
    <<if $j==0>>
        <<set $j=1>>
        【你获得了：家的感觉】
    <<endif>>
<<jump 走廊>>
===




title: 天台
tags:
position: 250,-2611
---
<<show_obj "天台.png">>
<<if $gameStage == 0>>
    【你站在教学楼的楼顶，视野开阔。阳光照在头顶有些发烫，风也暖暖的。天文台的环形走廊高高的，阿灿正靠在上面发呆。】
    阿灿: 喂！上来！
    me: 你刚才说…我们要修谁？
    阿灿: 你睡糊涂了吧？人怎么能被修呢？只有机器才用修的啊。
    阿灿: 亏你还想做医生呢！
    me: 我…
    me: 我睡糊涂了。
    阿灿指向了天文台。
    阿灿: 我们要修这个啊。
    阿灿: 不过…它的入口在哪里呢……奇怪。
    阿灿: 这下可怎么办啊……
    <<set $gameStage = 1>>
    <<set $ppStage=2>>
    <<set $stStage=2>>
<<elseif $gameStage == 1>>
    【你站在教学楼的楼顶，视野开阔。阳光照在头顶有些发烫，风也暖暖的。天文台的环形走廊高高的，阿灿正靠在上面发呆。】
<<elseif $gameStage == 2>>
    【你站在教学楼的楼顶，视野开阔。阳光照在头顶有些发烫，风也暖暖的。天文台的环形走廊高高的，阿灿正看着女孩在天文台的墙壁上画画。】
<<elseif $gameStage == 3>>
    【你站在教学楼的楼顶，视野开阔，天蓝蓝的，风也有点儿冷。空气中好像飘着某种气味…快到晚饭时间了，该抓紧了。】
<<endif>>

->检查
    ->窗户
        天文台下面有一排窗户。里面看起来是一个布满灰尘的走廊，走廊的两端没有门，也没有窗。
        很奇怪。似乎从来没有人进去过，也从来没有人能进去。
    ->地上<<if $gameStage==1>>
        地上排布着黑乎乎脏兮兮的隔热砖。太阳把地板晒得很烫。
        门在哪里呢？
        阿灿: 你在找什么啊？入口怎么可能在地上啦。
        <<if $scj==0>>
            <<set $scj=1>>
            你注意到了不起眼角落里的什么东西。
            【获得：矢车菊】
        <<endif>>
        你直起腰。背上的衣服沾满了汗，垂坠下来，带进凉飕飕的空气。
    ->远眺<<if $gameStage>2>>
        小镇的尽头是一座绿绿的小山丘，小山丘的那边是另一座小山丘，小山丘的那边是另一座小山丘……
    
->上去<<if $gameStage==1>>
    【环形走廊很高，你走到阿灿身边。】
    阿灿: 你找到门在哪里了吗？
    me: 还没呢。
    阿灿: 啊？这下怎么办啊。我还怎么变成星星啊……
    ->远眺
        <<if $gameStage==1>>
            阿灿: 你知道纽约吗？
            me: 嗯哼。
            阿灿: 你看到那边那座山了吗？那座山的后面就是纽约。
            你眯起眼睛使劲向远处往，但远处好象被什么雾笼盖住了。
            me: 海呢？
            阿灿: 海？
            me: 我们和纽约之间隔了一个海啊。
            阿灿: 那么，那座山的后面就是海。你知道我意思就行。
            阿灿: 好了，我们快去找入口在哪里吧。
        <<endif>>
    ->下去

->上去<<if $gameStage==2>>
    阿灿: …对啦，对啦！
    女孩正对着一扇破旧的金属门，看起来这扇门已经很久没有打开过了。你轻轻一推，门就打开了。
    女孩: 我不该这么做的…她会发现的……
    阿灿: 没错，所以我们得赶紧了。要是被她发现…可有我们好受的。
    阿灿: 快来！
    阿灿自顾自地钻了进去，留下女孩在旁边紧张地看着你。
    女孩: 我不该来这的……
    <<set $gameStage =3>>
    ->进去
        你进门又走上一圈旋转楼梯，进入了一个昏暗圆形的房间。
        <<jump 天文台>>
    ->下去

->天文台<<if $gameStage>1>>
    【环形走廊很高，金属架子随着你的脚步发出吱呀吱呀的声音。天文台里很黑，传出悉悉索索的金属声。】
    ->进入
        你进门又走上一圈旋转楼梯，进入了一个昏暗圆形的房间。
        <<jump 天文台>>
    ->下去
->下楼
    <<jump 走廊>>
<<jump 天台>>
===




title: 天文台
tags:
position: 250,-2611
---
<<show_obj "天文台.png">>
【你站在一间昏暗的圆形房间里。房间的正中央是一台天文望远镜，看起来很久没人用了。地上、桌上，遍布着灰尘】
阿灿把眼睛死死地贴在目镜上，嘴巴呆呆地张着。
->观察
    ->日历
        黄黄的日历的顶端印着几个数字，2后面跟着好多个0。
        你伸手一碰，那一页日历就像薄脆一样碎了。
        下面的一页上面也印着几个数字，看起来和上一页一样。
    ->望远镜
        你从来没有见过那么大的望远镜。
        这么大的望远镜，能看到海边吗？
    ->仪器
        这些仪器看着很像你工作用的工具。其中一个屏幕上写着大大的“ETHOS”……
        ……不对，你真的有那个工作吗？你只是一个学生吧。
->阿灿
    阿灿: 真美啊……
    me: 喂。
    阿灿: 可是要怎么上去呢……
    me: 看到什么了？
    阿灿: 快来！
    他把身体让向一侧，眼睛闪烁着兴奋的光芒。
    ->看
        你看过去，目镜里面是一片黑暗。
        <<if $gameStage==3>>
            <<hide_obj>>
            me: ……什么也没有啊。
            阿灿: 眼睛贴紧一点。
            你用力把眼眶按在目镜框上，这下是一点光也看不见了。
            me: 还是什么也没有啊。
            阿灿: 你再看看？
        <<endif>>
            黑暗中逐渐出现了一些光点。
            <<show_obj "星空.png">>
            阿灿: 看到什么了？
            me: ……
            阿灿: 我帮你调一下，这样你就能看得更近一些……
            me: 等会！
            ->离开目镜
                你猛地把眼睛从目镜上挪开。
                现在还不是离开的时候……
            ->继续看
                你迟疑了一会，画面动了起来。
                <<hide_obj>>
                阿灿: 只要这样就可以……
                阿灿的声音飞速地消失在了身后。
                me: 阿灿？
                ……
                me: 姐姐？
                <<jump 虚空>>
    ->回去
        你摇了摇头，阿灿急匆匆地把眼睛贴回在目镜上。
->出去
    <<jump 天台>>
<<jump 天文台>>
===




title: 虚空
tags:
position: 250,-2611
---
【你站在无尽的黑暗之中。更准确地说，是飘着。或者更准确地说，你感受不到你的身体了。】
->向星空
    你尝试飞离地球……
    远处出现了白色的光点……
    <<show_obj "星空.png">>
    <<jump 海边>>
->回头
    <<if $eathSeen==false>>
        <<set $earthSeen=true>>
        你回过头……
        <<show_obj "虚空.png">>
        me: 阿灿！
        你感觉声音是从自己的头颅传来的，像被闷在气球里。
    <<else>>
        你尝试飞向你来时的方向……
        你感觉自己移动了很远的距离，但远处那个球体好像一点也没有变大。
    <<endif>>
<<jump 虚空>>
===




title: 海边
tags:
position: 250,-2611
---
【你坐在海滩边上。海浪冲刷着你的脚趾，然后又迅速地退下去。空气粘腻得难以呼吸，天灰蒙蒙的，像一个巨大的罩子。】
姐姐: 还好你还是来了。
<<show_obj "海边.png">>
me: 姐姐？
姐姐: 你不该来这的……你看你，差点就回不来了。
姐姐: 迷路的时候，总是来找姐姐，好吗？
me: 好。
你感到嘴里的声音变得不自然。嘴里好像有什么东西，硬硬的。
你把嘴里的东西吐出来。是一颗牙齿。你的牙床空落落的，一阵酸痛。
me: 我…
姐姐: 你真的该回去了。
me: 怎么会这样……
姐姐: 梦都是假的。不要沉迷于梦里……
姐姐: 你的时间不多了…你必须要打起精神来。
me: 姐姐？
姐姐: 做你该做的事情。听到了吗？做你该做的事情。
me: 我…该做的事情？
你转过头看向她，就在这一瞬间，你感受到了一阵强烈的推力。
me: 姐姐！
<<hide_obj>>
【你猛地从床上坐起】
me: …啊……
me: 头好痛。
me: 啧……
你看向自己的手，手里什么也没有。
me: 都是假的……吗？
me: ……
<<NextYarn>>
===















title: 泳池
tags:
position: 250,-2611
---
<<show_obj "泳池.png">>
【你站在一个通壁贴满白色瓷砖的房间内，泳池的水光在天花板荡漾，外面的天蓝得像一块屏幕。】
<<if $gameStage == 1>>
    一个穿着泳裤的男孩正在做热身运动~一边唱歌一边热身~
<<else>>
    一个穿着泳裤的男孩正在泳池里游泳~
    他游完一圈，紧接着就掉头游下一圈。就这样一圈又一圈地游~
<<endif>>
->检查
    ->泳池
        泳池里的水汩汩地晃动，空气中充满着活力的氯味~
        <<if $stStage == 2>>
            你仔细一看，在水里看到了一个黑色的物体。
        <<endif>>
        ->跳进水中
            扑通！
            你的身体像气球一样~从水里浮了起来~
            <<if $swam == 0>>
                <<set $swam=1>>
                ->挥动双手
                咻！你向前移动了一小段距离。
               ->蹬腿
                咻！你又向前移动了一小段距离。
                你比你想象的更会游泳。    
            <<endif>>
            <<jump 泳池里>>
        ->返回
    ->天花板
        水光一会变成一只鸭子，一闪而过，又变成了一只蝴蝶。
        你感觉有点晃眼。
    ->窗外 
        你伸头向外望去，上面是蓝蓝的天空，下面也是蓝蓝的天空~     
->男孩
    <<if $gameStage == 1>>
        男孩: 你也来游泳啦？
        me: 我不会游泳。
        男孩: 这水很浅~别怕~你比你想象的更会游泳~！
        me: 我…我怕漏电呢。
        男孩: 说啥呢！哪来的电~
        男孩: 你是说抽筋吧！
        男孩: 只要~好好热身~就~不怕抽筋~
        男孩哼着歌，开始做伸展运动~
    <<elseif $stStage<4>>
        男孩: 我的泳帽！
        说着他把头扎入了水下。
        男孩: 掉了！帮我
        说着他又把头扎入了水下。
        男孩: 找找！
        他看起来很忙的样子。
    <<else>>
        男孩: 你做得！
        男孩: 很好！
        男孩一圈又一圈地游~永不停歇~
    <<endif>>
->返回
    <<jump 走廊>>
<<jump 泳池>>
===




title: 泳池里
---
->游向男孩
    <<if $swam<4>>
        男孩: 跟上！节奏！
        男孩一蹬腿，远远地把你甩在身后。
        <<set $swam=$swam+1>>
    <<elseif $stStage==3>>
        me: 等等！
        me: 我！
        me: 你的！
        me: 泳帽！
        me: （咳咳）
        男孩: 别管什么！
        男孩: 泳帽了！
        男孩: 跟上我的！
        男孩: 节奏！
        男孩一蹬腿，远远地把你甩在身后。
        <<set $stStage=4>>
    <<elseif $stStage==4>>
        男孩: 做得很好！跟上！
        男孩一蹬腿，远远地把你甩在身后。
    <<endif>>
->游向黑色物体<<if $stStage==2>>
    你像小船一样漂向那个黑色的物体~
    【你获得了：泳帽】
    <<set $stStage=3>>
->游向岸边
    你在游离泳池时呛了好几口水。
    me: 咳咳……
    水像瀑布一样从你身上滴落，在脚下形成一滩水。
    <<if $stStage<4>>
        你感觉身体好重，像戳破的气球落回了地面。
    <<else>>
        你感觉充满了活力~
    <<endif>>
    <<jump 泳池>>
<<jump 泳池里>>
===




title: 走廊深处
tags:
position: 250,-2611
---
<<show_obj "走廊深处.png">>
走廊把你引向了一个深不见底的天井。
->观察
    你把头伸出扶手向外望。这里的空气冰凉而潮湿，像一滩死水。
    ->亮光处
        你看到某一层的走廊似乎传出光亮。
        ->过去
            你走向了一侧的楼梯间，向下走去。
            <<hide_obj>>
            你仿佛听到某一层有人说话的声音。你越接近目的地，声音越明显。
            <<jump 走廊尽头>>
        ->缩回头
    ->最深处
        你向下看过去，隐约能够看见地面。但那里太黑了，几乎什么也看不清。
        ->过去
            你走向了一侧的楼梯间，向下走去。
            <<hide_obj>>
            ……
            <<jump 走廊底层>>
        ->缩回头
    ->凭感觉
        你听不见一点声响，也看不见一点动静。
        但你的直觉告诉你这个天井里的某处有什么东西正在游荡。
    你迅速把头缩了回去，有一种摆脱被注视的感觉。
->朝天井里喊
    me: 喂！
    回声: 喂！
    me: 我在这里！
    回声: 我在这里！
    你总觉得那个回声不像是你的声音。
->回去
    你转身向回走。身后的黑暗仿佛正啃咬着你的鞋跟和后背。
    你加快脚步，进而跑了起来。
    <<jump 走廊>>
<<jump 走廊深处>>
===




title: 走廊底层
tags:
position: 250,-2611
---
<<show_obj "走廊底层.png">>
->进去
    你鼓足勇气尝试靠近这片黑暗。
    <<hide_obj>>
    你越是靠近，就越感到面前仿佛有一个人也在靠近你。
    ->继续前进
        你又走出了两步，让黑暗完全把你包裹。面前那个气息声更明显了。
        ->继续前进
            在黑暗中，你感觉脚尖仿佛碰到了什么东西。
            你伸出手去，黑暗在你面前凝结成了一堵墙，把你的身体和你的气息都挡了回去。
            刚才听到的正是你的回声。
            现在回声听起来像是从四面八方很近地地方传来的了。
            你猛地回过头，不知道什么时候来时的那扇门已经变得如此遥远了。
            心脏突突地跳，恐惧击穿了你的理智。你向那扇透出光亮的门狂奔而去。
        ->退回去
    ->退回去
->回头
    你转身向上走。身后的黑暗仿佛正啃咬着你的鞋跟和后背。
    你加快脚步，进而跑了起来。
    <<hide_obj>>
    你气喘吁吁地回到了刚才的走廊。
    <<jump 走廊深处>>
<<jump 走廊底层>>
===




title: 走廊尽头
tags:
position: 250,-2611
---
<<show_obj "走廊尽头.png">>
【你站在一道潮湿阴冷的走廊。一个带着厚厚眼睛的女孩正就着鱼缸传出的昏暗的紫光，一边写作业一边自言自语。】
->观察
    ->金鱼缸
        金鱼在狭小的鱼缸里来回打转。你数了数，一共4只红色的，1只黑色的。
        它们从一边游到另一边，又从另一边游回来。
        它们为什么要游呢？
    ->光亮处
        你听不见走廊的尽头的声音，但通过刺眼的阳光来看，看起来像是室外。
        ->出去
            眼镜女孩: 喂！我说过了，没有人被允许出去！
            你吓了一跳，感觉身体仿佛自己动了起来，退了回去。
        ->回去
    ->墙上
        墙上是密密麻麻的奖状。你看不清名字，但能认出都是同一个人的。
->眼镜女孩
    你看不懂她正在写的题目。
    眼镜女孩: 谁让你到这来的？回去。
    me: 我……
    眼镜女孩: 你烦不烦？老师说过没有人能从这里出去。你快走吧。
    她的注意力又迅速地转移到她的作业去了。
->回去
    你转身向回到楼梯间向上走，眼镜女孩的读书声远远地在楼梯间里回荡，像是从四面八方传来的。
    <<jump 走廊深处>>
<<jump 走廊尽头>>
===
